@@echo off

echo MSU SAP GUI Installation Script
echo.
echo David Graff
echo Michigan State University
echo Physical Plant
echo <a href="/cgi-bin/wa?LOGON=A3%3Dind1302%26L%3DMSUNAG%26E%3D7bit%26P%3D497216%26B%3D--part-KRy4ZeCIzn5IBGRKNY0Ei-RFLcf6gcbSm5uk1RdCGQRpy%26T%3DTEXT%252FPLAIN%3B%2520name%3D%2522SAP%2520GUI%2520Install.txt%2522%26N%3DSAP%2520GUI%2520Install.txt" target="_parent" >[log in to unmask]</a>

set SourceDir=\\server\share
set Installer=msusapgui_730.exe

echo.
echo Cleaning up shortcuts
del /f /q "%public%\Desktop\SAP Logon.lnk" > nul
del /f /q "%allusersprofile%\Desktop\SAP Logon.lnk" > nul

echo.
Echo Check for currently installed SAP GUI 7.30 - Feb 2013
reg query HKLM\Software\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\SAPGUI710 | find "7.30 Compilation 1"> nul && goto installed
reg query HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\SAPGUI710 | find "7.30 Compilation 1" > nul && goto installed

echo.
Echo Installing SAP GUI
eventcreate /id 1 /l Application /so "SAP GUI Installation" /t INFORMATION /d "SAP GUI installation process executing." > nul
"%SourceDir%\%Installer%" /silent || goto failed
del /f /q "%public%\Desktop\SAP Logon.lnk" > nul
del /f /q "%allusersprofile%\Desktop\SAP Logon.lnk" > nul
eventcreate /id 1 /l Application /so "SAP GUI Installation" /t INFORMATION /d "SAP GUI installation process complete." > nul
echo Installation Complete

exit /b 0

:installed
exit /b 0

:failed
eventcreate /id 1 /l Application /so "SAP GUI Installation" /t ERROR /d "SAP GUI installation process failed." > nul
echo Installation Failed
exit /b 1